The ArduinoOTA library is a library that allows to update the Arduino program (and ESP3226, ESP32) wirelessly in Wi-Fi. It is an essential library when developing connected objects. It allows to update the program without having to disassemble the microcontroller (Arduino, ESP8266, ESP32) to connect it to his computer. This library was originally developed to update the Arduino programs, it is perfectly supported by the ESP8266 and ESP32. For this tutorial, we will only address the case of ESP8266.

Install the ArduinoOTA library for ESP8266 on the Arduino IDE

The ArduinoOTA library is integrated into the ESP8266 library. There is nothing more to install. If you’re new to ESP, here’s how to install the ESP library and support. Open the preferences (from the Arduino menu) and add to the list of packages this one

http://arduino.esp8266.com/stable/package_esp8266com_index.json

Then go to the map manager and look for esp8266, then click install.

After installation, new examples have been added to the sample menu. Select your ESP8266 card to display the available samples. Open the BasicOTA example in the ArduinoOTA submenu

This program contains everything you need to manage wireless upgrade in your ESP projects.

#include <ESP8266WiFi.h>
#include <ESP8266mDNS.h>
#include <WiFiUdp.h>
#include <ArduinoOTA.h>

const char* ssid = "..........";
const char* password = "..........";

void setup() {
  Serial.begin(115200);
  Serial.println("Booting");
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  while (WiFi.waitForConnectResult() != WL_CONNECTED) {
    Serial.println("Connection Failed! Rebooting...");
    delay(5000);
    ESP.restart();
  }

  // Port defaults to 8266
  // ArduinoOTA.setPort(8266);

  // Hostname defaults to esp8266-[ChipID]
  ArduinoOTA.setHostname("Demo OTA ESP8266");

  // No authentication by default
  ArduinoOTA.setPassword((const char *)"123");

  ArduinoOTA.onStart([]() {
    Serial.println("Start");
  });
  ArduinoOTA.onEnd([]() {
    Serial.println("\nEnd");
  });
  ArduinoOTA.onProgress([](unsigned int progress, unsigned int total) {
    Serial.printf("Progress: %u%%\r", (progress / (total / 100)));
  });
  ArduinoOTA.onError([](ota_error_t error) {
    Serial.printf("Error[%u]: ", error);
    if (error == OTA_AUTH_ERROR) Serial.println("Auth Failed");
    else if (error == OTA_BEGIN_ERROR) Serial.println("Begin Failed");
    else if (error == OTA_CONNECT_ERROR) Serial.println("Connect Failed");
    else if (error == OTA_RECEIVE_ERROR) Serial.println("Receive Failed");
    else if (error == OTA_END_ERROR) Serial.println("End Failed");
  });
  ArduinoOTA.begin();
  Serial.println("Ready");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
}

void loop() {
  ArduinoOTA.handle();
}

Before reversing the program, change the ssid variables (Wi-Fi network to which to connect) and password (password).

Here, the program uses the ESP8266WiFi library to connect to the network. You can also use the WiFiManager library presented earlier.

Once the connection is established, it is possible to define additional (optional) parameters:

• SetPort: by default the communication port is 8266. It is not very useful to change it unless it is already in use. For example, for a project integrating UDP communication.
• SetHostname: This is probably the most important option. It allows you to assign a name to the ESP8266. If you have a lot of objects on your network, it will be much easier to identify it by name than by an identifier built automatically from the serial number.
• SetPassword: used to request a password from the Arduino IDE before running an update. Practice if you work at several or in a school.

There are four other ways to connect treatments in the following cases:

• OnStart: code to run when the update is started
• OnEnd: idem at the end
• OnProgress: during the progress
• OnError: and on error

You will not need to add treatments in most cases. In particular, these functions allow us to remain informed of the smooth running of operations.

At the end of the setup, once all functions have been defined, start the wireless update support by calling the begin () method.

Finally, for everything to work, it is necessary to call the ArduinoOTA.handle () method in the loop () loop.

Wireless Update Test

Upload the program and open the Terminal to verify that the ESP8266 is properly connected to the Wi-Fi network.

The Arduino IDE automatically detects devices that support remote update. They are added to the list of ports in a new section called Network ports.

To update the program, simply select the ESP as the port instead of the usual serial port. Then upload the program as usual. Here, as a password is required, an input window appears in the IDE. It is requested only once

The remote update (or failure) of the remote update can be tracked directly from the Arduino IDE.

It is not possible to open the serial monitor with wireless setup. A small Web interface is required. Read this tutorial to learn how to add a Web server and HTML interface to an ESP8266 project. To go further, here is a series of articles dealing with the subject

• Pi Imager and the configuration wizard simplify the installation of Raspberry Pi OS (old Raspbian) 25 June 2020
• Home Assistant. Get started on Raspberry Pi 4. Procedure 2020 25 June 2020
• Install Domoticz on NAS Synology DS718+ with Docker or virtual machine under Debian Buster 1 June 2020
• Install the MQTT Mosquitto broker on NAS Synology (DSM 6.2+) with Docker 6 April 2020
• Use the plugins on Domoticz. Manual installation or via Python Plugin Manager 1 April 2019
• MQTT router with Node-RED, connect all your Sonoff Tasmota modules to cloudMQTT 29 March 2019
• #Hack of Sonoff S26 WiFi smart plug, Tasmota firmware installation 27 March 2019
• CloudMQTT test, free online MQTT broker. Control Domoticz with the JSON API 25 March 2019
• Securing Domoticz with Let’s Encrypt certificate, access from HTTPS internet 22 March 2019
• Homy, iOS / Android home automation application to control a server or DIY connected objects 20 December 2018
• Xiaomi Mijia Honeywell Smoke Detector Test with Domoticz, Emergency Notification with PushOver 13 September 2018
• Xiaomi Aqara now compatible with Apple Homekit, new Vibration Sensor and Honeywell Natural Gas Detector 11 September 2018
• #Test Zigbee2MQTT gateway. Part 2, include Xiaomi Aqara or Mijia accessories to Domoticz with Node-RED [update] 10 September 2018
• #Test Zigbee2MQTT project, hack of the Xiaomo Aqara Smart Home Gateway. Part 1: assembly, demo with Node-RED, 3D printed case [update] 7 September 2018
• The diyprojects application also available on iOS and Android, first mobile project with Ionic 3 5 September 2018

• ESP8266, Deep Sleep mode test, wake up with a PIR motion detector
• #Guide: which ESP8266 module to choose, power supply, how to program it in C++ with Arduino IDE, MicroPython, ESP Easy
• #Guide: Which ESP32 development board to choose to develop DIY connected objects
• WebSocket communication with an ESP8266 or Arduino in Python. Test with the ws4py library on Raspberry Pi
• Publish the CO2 concentration of an MH-Z19 sensor to Domoticz, Arduino code compatible ESP32 / ESP8266
• Unpacking the Wemos D1 R2, ESPDuino clone, ESP8266 development board in Arduino Uno format